AC-Archive
Autoconf Macro Archive

ac-archive.sf.net: - Project CVS - Download
Macro Index
- AM Support
- C++ Support
- C Support
- Fortran Support
- Java Support
- Cross Compilation
- Installed Packages
- Miscellaneous
- LaTeX Support
- Uncategorized
- archive macros
- adl's macros
- bkorb's macros
- guidod's macros
- latex's macros
- other's macros
- rleigh's macros
- obsoleted macros
- released macros
- search index

Documentation
- Contribute!
- History
- acincludedir m4
- acinclude (tool)
- macro howto
- ax tricks
- maintainers
- License
- Topics

generated...
2007-08-05

(C) 2007 guidod
Download the M4 Source.

ac_lib_id3

Back to the Main Page.

Synopsis
AC_LIB_ID3([ACTION-IF-TRUE], [ACTION-IF-FALSE])
, 
Version

2005-04-18

Author

Oskar Liljeblad <oskar@osk.mine.nu>

License

gpl2

Category

cryp.to ac-archive's Installed Packages (released)

Documentation

This macro will check for the existence of id3lib (http://id3lib.sourceforge.net/). It does this by checking for the header file id3.h and the id3 library object file. A --with-id3lib option is supported as well. The following output variables are set with AC_SUBST:

 ID3_CPPFLAGS
 ID3_LDFLAGS
 ID3_LIBS

You can use them like this in Makefile.am:

 AM_CPPFLAGS = $(ID3_CPPFLAGS)
 AM_LDFLAGS = $(ID3_LDFLAGS)
 program_LDADD = $(ID3_LIBS)

Additionally, the C preprocessor symbol HAVE_ID3LIB will be defined with AC_DEFINE if id3lib is available.

M4 Source Code
AC_DEFUN([AC_LIB_ID3], [
  AH_TEMPLATE([HAVE_ID3LIB], [Define if id3lib is available])
  AC_ARG_WITH(id3lib, [  --with-id3lib=DIR       prefix for id3 library files and headers], [
    if test "$withval" = "no"; then
      ac_id3_path=
      $2
    elif test "$withval" = "yes"; then
      ac_id3_path=/usr
    else
      ac_id3_path="$withval"
    fi
  ],[ac_id3_path=/usr])
  if test "$ac_id3_path" != ""; then
    saved_CPPFLAGS="$CPPFLAGS"
    CPPFLAGS="$CPPFLAGS -I$ac_id3_path/include"
    AC_CHECK_HEADER([id3.h], [
      saved_LDFLAGS="$LDFLAGS"
      LDFLAGS="$LDFLAGS -L$ac_id3_path/lib"
      AC_CHECK_LIB(id3, ID3Tag_New, [
        AC_SUBST(ID3_CPPFLAGS, [-I$ac_id3_path/include])
        AC_SUBST(ID3_LDFLAGS, [-L$ac_id3_path/lib])
        AC_SUBST(ID3_LIBS, [-lid3])
	AC_DEFINE([HAVE_ID3LIB])
        $1
      ], [
        :
        $2
      ])
      LDFLAGS="$saved_LDFLAGS"
    ], [
      AC_MSG_RESULT([not found])
      $2
    ])
    CPPFLAGS="$saved_CPPFLAGS"
  fi
])